API Gateway invoking Lambda function with Terraform

In this post, we'll setup an API Gateway that invokes Lmabda function that takes an input. We'll do that via Terraform.

We'll follow the guidelines from:

1. Resource: aws_api_gateway_resource.
2. Serverless Applications with AWS Lambda and API Gateway

Here is the manifest file, api_gateway.tf:

resource "aws_api_gateway_rest_api" "examplepy" {
  name        = "Serverlessexamplepy"
  description = "Terraform Serverless Application Example python"
}

resource "aws_api_gateway_resource" "number" {
  parent_id   = aws_api_gateway_rest_api.examplepy.root_resource_id
  rest_api_id = aws_api_gateway_rest_api.examplepy.id
  path_part   = "{${var.resource_name}+}"
}

resource "aws_api_gateway_method" "number" {
   rest_api_id   = aws_api_gateway_rest_api.examplepy.id
   resource_id   = aws_api_gateway_resource.number.id
   http_method   = "GET"
   authorization = "NONE"
}

resource "aws_api_gateway_integration" "lambdapy" {
   rest_api_id = aws_api_gateway_rest_api.examplepy.id
   resource_id = aws_api_gateway_method.number.resource_id
   http_method = aws_api_gateway_method.number.http_method

   integration_http_method = "POST"
   type                    = "AWS"
   uri                     = aws_lambda_function.examplepy.invoke_arn
   passthrough_behavior = "WHEN_NO_TEMPLATES"
   
   request_templates = {
    "application/json" = <<EOF
{
  "hour" : $input.params('hour')
  }
EOF
  }
}

resource "aws_api_gateway_method" "number_rootpy" {
   rest_api_id   = aws_api_gateway_rest_api.examplepy.id
   resource_id   = aws_api_gateway_rest_api.examplepy.root_resource_id
   http_method   = "GET"
   authorization = "NONE"
}

resource "aws_api_gateway_integration" "lambda_rootpy" {
   rest_api_id = aws_api_gateway_rest_api.examplepy.id
   resource_id = aws_api_gateway_method.number_rootpy.resource_id
   http_method = aws_api_gateway_method.number_rootpy.http_method

   integration_http_method = "POST"
   type                    = "AWS"
   uri                     = aws_lambda_function.examplepy.invoke_arn
#   passthrough_behavior = "WHEN_NO_TEMPLATES"
#   request_templates = {
#    "application/json" = <<EOF
#{"hour" : $input.params('hour')}
#EOF
# }
}

resource "aws_api_gateway_method_response" "response_200" {
 rest_api_id = aws_api_gateway_rest_api.examplepy.id
 resource_id = aws_api_gateway_resource.number.id
 http_method = aws_api_gateway_method.number.http_method
 status_code = "200"
 
 response_models = { "application/json" = "Empty"}
}

resource "aws_api_gateway_integration_response" "IntegrationResponse" {
  depends_on = [
     aws_api_gateway_integration.lambdapy,
     aws_api_gateway_integration.lambda_rootpy,
  ]
  rest_api_id = aws_api_gateway_rest_api.examplepy.id
  resource_id = aws_api_gateway_resource.number.id
  http_method = aws_api_gateway_method.number.http_method
  status_code = aws_api_gateway_method_response.response_200.status_code
  # Transforms the backend JSON response to json. The space is "A must have"
 response_templates = {
 "application/json" = <<EOF
 
 EOF
 }
}

# Model
# resource "aws_api_gateway_model" "MyDemoModel" {
# rest_api_id = "${aws_api_gateway_rest_api.examplepy.id}"
# name = "usermodel"
# description = "a JSON schema"
# content_type = "application/json"
# 
# #the payload of the POST request
# schema = <<EOF
# {
# "$schema": "http://json-schema.org/draft-04/schema#",
# "title": "usermodel",
# "type": "object",
# "properties": 
# {
# "callerName": { "type": "string" }
# }
# 
# }
# EOF
#}

resource "aws_api_gateway_deployment" "examplepy" {
   depends_on = [
     aws_api_gateway_integration.lambdapy,
     aws_api_gateway_integration_response.IntegrationResponse,
   ]

   rest_api_id = aws_api_gateway_rest_api.examplepy.id
   stage_name  = var.stage

}

output "base_url" {
  value = "${aws_api_gateway_deployment.examplepy.invoke_url}/${var.resource_name}"
}

Here is another manifest file for our lambda, lambda.tf:

terraform {
  required_providers {
    aws = {
      source = "hashicorp/aws"
    }
  }
}

provider "aws" {
   region = "us-east-1"
}

resource "aws_lambda_function" "examplepy" {
   function_name = "Serverlessexamplepy"

   # The S3 bucket should already exists
   s3_bucket = "bogo-terraform-serverless-examplepy"
   s3_key    = "v${var.app_version}/examplepy.zip"

   # "lambda_function" is the filename within the zip file (lambda_function.py) 
   # and "handler" is the name of the property 
   # under which the handler function was exported in that file.
   handler = "lambda_function.lambda_handler"
   runtime = "python3.8"

   role = aws_iam_role.lambda_execpy.arn
}

 # IAM role which dictates what other AWS services the Lambda function may access.
resource "aws_iam_role" "lambda_execpy" {
   name = "serverless_example_lambdapy"

   assume_role_policy = <<EOF
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Action": "sts:AssumeRole",
      "Principal": {
        "Service": "lambda.amazonaws.com"
      },
      "Effect": "Allow",
      "Sid": ""
    }
  ]
}
EOF

}

resource "aws_lambda_permission" "apigw" {
   statement_id  = "AllowAPIGatewayInvoke"
   action        = "lambda:InvokeFunction"
   function_name = aws_lambda_function.examplepy.function_name
   principal     = "apigateway.amazonaws.com"

   # The "/*/*" portion grants access from any method on any resource
   # within the API Gateway REST API.
   source_arn = "${aws_api_gateway_rest_api.examplepy.execution_arn}/*/*"
}

The variables are defined in variables.tf:

variable "app_version" {
    default = "1.0.0"
}

variable "stage" {
	default = "dev"
}

variable "resource_name" {
	default = "number"
}    

Python code, examplepy/lambda_function.py:

def lambda_handler(event, context):

    h = float(event['hour'])
    print(h)

    return {
        'past hours': h
    }    

The code takes an input from a query string (for example, url?hour=10) and simply returns it.

To put the code into a S3 bucket, we need create a bucker, zip and upload it:

$ aws s3 mb s3://bogo-terraform-serverless-examplepy
make_bucket: bogo-terraform-serverless-examplepy

$ zip examplepy.zip examplepy/lambda_function.py
adding: examplepy/lambda_function.py (deflated 21%)

$ aws s3 cp examplepy.zip s3://bogo-terraform-serverless-examplepy/
upload: ./examplepy.zip to s3://bogo-terraform-serverless-examplepy/v1.0.0/examplepy.zip

The files are available from Einsteinish/Terraform-AWS-API-Gateway-and-Lambda

Now, we are ready to deploy our lambda and API gateway:

$ terraform init

$ terraform apply -var="app_version=1.0.0" --auto-approve
base_url = "https://sa7lfskwkb.execute-api.us-east-1.amazonaws.com/dev/number"

We can get a reponse from the following query:

$ curl https://sa7lfskwkb.execute-api.us-east-1.amazonaws.com/dev/number?hour=10     
{"past hours": 10.0}

API Gateway:

Lambda:

AWS (Amazon Web Services)

1. AWS : EKS (Elastic Container Service for Kubernetes)
2. AWS : Creating a snapshot (cloning an image)
3. AWS : Attaching Amazon EBS volume to an instance
4. AWS : Adding swap space to an attached volume via mkswap and swapon
5. AWS : Creating an EC2 instance and attaching Amazon EBS volume to the instance using Python boto module with User data
6. AWS : Creating an instance to a new region by copying an AMI
7. AWS : S3 (Simple Storage Service) 1
8. AWS : S3 (Simple Storage Service) 2 - Creating and Deleting a Bucket
9. AWS : S3 (Simple Storage Service) 3 - Bucket Versioning
10. AWS : S3 (Simple Storage Service) 4 - Uploading a large file
11. AWS : S3 (Simple Storage Service) 5 - Uploading folders/files recursively
12. AWS : S3 (Simple Storage Service) 6 - Bucket Policy for File/Folder View/Download
13. AWS : S3 (Simple Storage Service) 7 - How to Copy or Move Objects from one region to another
14. AWS : S3 (Simple Storage Service) 8 - Archiving S3 Data to Glacier
15. AWS : Creating a CloudFront distribution with an Amazon S3 origin
16. AWS : Creating VPC with CloudFormation
17. AWS : WAF (Web Application Firewall) with preconfigured CloudFormation template and Web ACL for CloudFront distribution
18. AWS : CloudWatch & Logs with Lambda Function / S3
19. AWS : Lambda Serverless Computing with EC2, CloudWatch Alarm, SNS
20. AWS : Lambda and SNS - cross account
21. AWS : CLI (Command Line Interface)
22. AWS : CLI (ECS with ALB & autoscaling)
23. AWS : ECS with cloudformation and json task definition
24. AWS Application Load Balancer (ALB) and ECS with Flask app
25. AWS : Load Balancing with HAProxy (High Availability Proxy)
26. AWS : VirtualBox on EC2
27. AWS : NTP setup on EC2
28. AWS: jq with AWS
29. AWS & OpenSSL : Creating / Installing a Server SSL Certificate
30. AWS : OpenVPN Access Server 2 Install
31. AWS : VPC (Virtual Private Cloud) 1 - netmask, subnets, default gateway, and CIDR
32. AWS : VPC (Virtual Private Cloud) 2 - VPC Wizard
33. AWS : VPC (Virtual Private Cloud) 3 - VPC Wizard with NAT
34. DevOps / Sys Admin Q & A (VI) - AWS VPC setup (public/private subnets with NAT)
35. AWS - OpenVPN Protocols : PPTP, L2TP/IPsec, and OpenVPN
36. AWS : Autoscaling group (ASG)
37. AWS : Setting up Autoscaling Alarms and Notifications via CLI and Cloudformation
38. AWS : Adding a SSH User Account on Linux Instance
39. AWS : Windows Servers - Remote Desktop Connections using RDP
40. AWS : Scheduled stopping and starting an instance - python & cron
41. AWS : Detecting stopped instance and sending an alert email using Mandrill smtp
42. AWS : Elastic Beanstalk with NodeJS
43. AWS : Elastic Beanstalk Inplace/Rolling Blue/Green Deploy
44. AWS : Identity and Access Management (IAM) Roles for Amazon EC2
45. AWS : Identity and Access Management (IAM) Policies, sts AssumeRole, and delegate access across AWS accounts
46. AWS : Identity and Access Management (IAM) sts assume role via aws cli2
47. AWS : Creating IAM Roles and associating them with EC2 Instances in CloudFormation
48. AWS Identity and Access Management (IAM) Roles, SSO(Single Sign On), SAML(Security Assertion Markup Language), IdP(identity provider), STS(Security Token Service), and ADFS(Active Directory Federation Services)
49. AWS : Amazon Route 53
50. AWS : Amazon Route 53 - DNS (Domain Name Server) setup
51. AWS : Amazon Route 53 - subdomain setup and virtual host on Nginx
52. AWS Amazon Route 53 : Private Hosted Zone
53. AWS : SNS (Simple Notification Service) example with ELB and CloudWatch
54. AWS : Lambda with AWS CloudTrail
55. AWS : SQS (Simple Queue Service) with NodeJS and AWS SDK
56. AWS : Redshift data warehouse
57. AWS : CloudFormation
58. AWS : CloudFormation Bootstrap UserData/Metadata
59. AWS : CloudFormation - Creating an ASG with rolling update
60. AWS : Cloudformation Cross-stack reference
61. AWS : OpsWorks
62. AWS : Network Load Balancer (NLB) with Autoscaling group (ASG)
63. AWS CodeDeploy : Deploy an Application from GitHub
64. AWS EC2 Container Service (ECS)
65. AWS EC2 Container Service (ECS) II
66. AWS Hello World Lambda Function
67. AWS Lambda Function Q & A
68. AWS Node.js Lambda Function & API Gateway
69. AWS API Gateway endpoint invoking Lambda function
70. AWS API Gateway invoking Lambda function with Terraform
71. AWS API Gateway invoking Lambda function with Terraform - Lambda Container
72. Amazon Kinesis Streams
73. AWS: Kinesis Data Firehose with Lambda and ElasticSearch
74. Amazon DynamoDB
75. Amazon DynamoDB with Lambda and CloudWatch
76. Loading DynamoDB stream to AWS Elasticsearch service with Lambda
77. Amazon ML (Machine Learning)
78. Simple Systems Manager (SSM)
79. AWS : RDS Connecting to a DB Instance Running the SQL Server Database Engine
80. AWS : RDS Importing and Exporting SQL Server Data
81. AWS : RDS PostgreSQL & pgAdmin III
82. AWS : RDS PostgreSQL 2 - Creating/Deleting a Table
83. AWS : MySQL Replication : Master-slave
84. AWS : MySQL backup & restore
85. AWS RDS : Cross-Region Read Replicas for MySQL and Snapshots for PostgreSQL
86. AWS : Restoring Postgres on EC2 instance from S3 backup
87. AWS : Q & A
88. AWS : Security
89. AWS : Security groups vs. network ACLs
90. AWS : Scaling-Up
91. AWS : Networking
92. AWS : Single Sign-on (SSO) with Okta
93. AWS : JIT (Just-in-Time) with Okta